Solved

ms-dos variable @path doesn't include & symbol of path - workarounds?

Posted on 2008-10-17
7
737 Views
Last Modified: 2012-05-05
On any folders that have an & character in the folder name, the above (or below?) command seems to stop reading the name at that symbol.  For example, I have a folder called "A & A businees, inc."  When I run the forfiles command, the resultant command only shows "md c:\test\A " instead of md "c:\test\"A & A businees, inc."\TY08\Tax Returns"
It drops the & symbol and the rest of the name.  Ideas on how to overcome this?  I included the slashes so that I could get it to make folders with a space in the name - however, I'm not getting any folders with & in the name now.

Here's the catch:  If I run the second command included, the resultant command has the path correct (but isn't creating the directory as I wanted with a space.  I had to include the underscore.
1. forfiles /p c:\test /c "cmd /c if @isdir==TRUE md \"@path\TY08\Tax Returns\""
 
2. forfiles /p p:\ /c "cmd /c if @isdir==TRUE echo md @path\TY08\Tax_returns" > c:\fileorig.txt

Open in new window

0
Comment
Question by:bruderbell
7 Comments
 
LVL 38

Accepted Solution

by:
Shift-3 earned 400 total points
ID: 22744820
This may work better using the FOR command instead of FORFILES.

Paste the script below into a text file with a .cmd extension.  Running it will create the subfolders.

If you are going to run this from the command prompt rather than from a batch script, replace each instance of %%G with %G.


@echo off
setlocal
 
set folder=c:\test
 
for /F "tokens=*" %%G in ('dir "%folder%" /A:D /B') do md "%folder%\%%G\TY\Tax Returns"

Open in new window

0
 
LVL 95

Expert Comment

by:Lee W, MVP
ID: 22746009
If shift-3's comment doesn't work, it may be because & is used to join two commands on one command line.  For example:
C:\Temp\scripts>@echo firstline & @echo secondline
firstline
secondline

if you were not putting the & in a variable, you could probably escape it using ^ - for example,
C:\Temp\scripts>@echo firstline ^& @echo secondline
firstline & @echo secondline

Given this behavior and the possibility for problems, I would suggest your best solution is to search and replace every ampersand with the word "and"

For example, instead of using 'dir "%folder%" /A:D /B', make it two separate commands and do some editing:
Command 1:
dir "%folder%" /A:D /B>folderlist.txt

Then using notepad, do a quick search and replace, then run an if command similar to the one suggested above:
for /F "tokens=*" %%G in (folderlist.txt) do md "%folder%\%%G\TY\Tax Returns"

0
 
LVL 95

Expert Comment

by:Lee W, MVP
ID: 22746029
You can probably also get around this using the for command alone:

@echo off
setlocal
 
set folder=c:\test
 
for /F "tokens=1* delims=&" %%G in ('dir "%folder%" /A:D /B') do (
   If "%%H"=="" (
      md "%folder%\%%G\TY\Tax Returns"
   ) Else (
      md "%folder%\%%G ^& %%H\TY\Tax Returns"
      REM The next line replaces the & with the word and in the folder name but is commented out at the moment.
      REM md "%folder%\%%G and %%H\TY\Tax Returns"
   )
)
0
3 Use Cases for Connected Systems

Our Dev teams are like yours. They’re continually cranking out code for new features/bugs fixes, testing, deploying, testing some more, responding to production monitoring events and more. It’s complex. So, we thought you’d like to see what’s working for us.

 
LVL 95

Expert Comment

by:Lee W, MVP
ID: 22746064
And as I think about it and re-read the question, you cannot replace the & without renaming existing folders... so scratch that.  There's another way you can probably get around this:



@echo off
setlocal
 
set folder=c:\test
 
Rem create sub folders for all clients with ampersands in their folder names
for /F "tokens=1* delims=&" %%G in ('dir "%folder%" /A:D /B ^| Find /i "&"') do md "%folder%\%%G ^& %%H\TY\Tax Returns"
 
Rem create sub folders for all clients without ampersands in their folder names
for /f "tokens=*" %%G in ('dir %folder% /ad /b ^| Find /i /v "&"') do md "%folder%\%%G\TY\Tax Returns"

Open in new window

0
 
LVL 38

Expert Comment

by:Shift-3
ID: 22746268
Is there some problem with my method?
0
 
LVL 21

Assisted Solution

by:AmazingTech
AmazingTech earned 100 total points
ID: 22753815
Here give this a go.

If you're running it from the command line then use this:
forfiles /p c:\test /c "cmd /c if @isdir==TRUE for %a in (@path) do md \"%~a\TY08\Tax Returns\""

forfiles /p c:\test /c "cmd /c if @isdir==TRUE for %%a in (@path) do md \"%%~a\TY08\Tax Returns\""

Open in new window

0
 

Author Closing Comment

by:bruderbell
ID: 31507886
Both of your solutions fix the problem, apparently through the use of different variables than those that are available simply in the /c cmd format.  Thanks!
0

Featured Post

Courses: Start Training Online With Pros, Today

Brush up on the basics or master the advanced techniques required to earn essential industry certifications, with Courses. Enroll in a course and start learning today. Training topics range from Android App Dev to the Xen Virtualization Platform.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Suggested Solutions

YESTERDAY YESTERDAY.BAT is inspired by a previous article I wrote entitled: TOMORROW.BAT (http://www.experts-exchange.com/OS/Microsoft_Operating_Systems/MS_DOS/A_4196-Advanced-Batch-File-Programming-TOMORROW-BAT.html). The crux of this batch f…
You may have already been in the need to update a whole folder stucture using a script. Robocopy does it well and even provides a list of non-updated files in a log (if asked to). Generally those files that were locked by a user or a process by the …
This Micro Tutorial will give you a basic overview how to record your screen with Microsoft Expression Encoder. This program is still free and open for the public to download. This will be demonstrated using Microsoft Expression Encoder 4.
This video shows how to quickly and easily add an email signature for all users on Exchange 2016. The resulting signature is applied on a server level by Exchange Online. The email signature template has been downloaded from: www.mail-signatures…

776 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question