I dont know what version you are running, but it should be possible:

http://support.microsoft.com/kb/261002

@drewha1969: I'm using IIS7, for Windows 2008

@leew: I understand. But eventhough it's just a small txt or images, I don't want to store anything into Drive C: that will make the drive space small in the future...

@itkamaraj: How? Please... :-) Will it affect my Default Website if I move the IIS to another drive->folder?

You will have to change the paths to EVERYTHING.

You are focusing your time and energy on the wrong thing.  Who told you you should move this?  Put simply, you don't have to put web sites in it.   I leave the inetpub folder on the drive but put all my web sites on another disk.

As still another option, you can mount (link/use a junction) to another disk into the inetpub folder and even though it APPEARS to be on C: it's not.  

Exactly. I do the same thing, I mjust move my roots to a different Drive.
Since you are using IIS7, you can use MOVEIISROOT.BAT. Permissions are remained intact and sites are updated to the new locations.
1. open CMD
2. browse to the directory where moveiisroot.bat exists.
3. type MOVEIISROOT.BAT F  
       F is the drive you want to change hte letter to.  This could be E, G etc...

Cheers,
Hades666  

REM PLEASE BE AWARE: SERVICING (I.E. HOTFIXES AND SERVICE PACKS) WILL STILL REPLACE FILES 
REM IN THE ORIGINAL DIRECTORIES. THE LIKELIHOOD THAT FILES IN THE INETPUB DIRECTORIES HAVE 
REM TO BE REPLACED BY SERVICING IS LOW BUT FOR THIS REASON DELETING THE ORIGINAL DIRECTORIES 
REM IS NOT POSSIBLE. 
@echo off 
IF "%1" == "" goto err 
setlocal 
set MOVETO=%1:\ 
REM simple error handling if drive does not exist or argument is wrong 
IF NOT EXIST %MOVETO% goto err 
REM Backup IIS config before we start changing config to point to the new path 
%windir%\system32\inetsrv\appcmd add backup beforeRootMove 
REM Stop all IIS services 
iisreset /stop 
REM Copy all content 
REM /O – copy ACLs 
REM /E – copy sub directories including empty ones 
REM /I – assume destination is a directory 
REM /Q – quiet 
REM echo on, because user will be prompted if content already exists. 
echo on 
xcopy %systemdrive%\inetpub %MOVETO%inetpub /O /E /I /Q 
@echo off 
REM Move AppPool isolation directory 
reg add HKLM\System\CurrentControlSet\Services\WAS\Parameters /v ConfigIsolationPath /t REG_SZ /d %MOVETO%inetpub\temp\appPools /f 
REM Move logfile directories 
%windir%\system32\inetsrv\appcmd set config -section:system.applicationHost/sites -siteDefaults.traceFailedRequestsLogging.directory:"%MOVETO%inetpub\logs\FailedReqLogFiles" 
%windir%\system32\inetsrv\appcmd set config -section:system.applicationHost/sites -siteDefaults.logfile.directory:"%MOVETO%inetpub\logs\logfiles" 
%windir%\system32\inetsrv\appcmd set config -section:system.applicationHost/log -centralBinaryLogFile.directory:"%MOVETO%inetpub\logs\logfiles" 
%windir%\system32\inetsrv\appcmd set config -section:system.applicationHost/log -centralW3CLogFile.directory:"%MOVETO%inetpub\logs\logfiles" 
REM Move config history location, temporary files, the path for the Default Web Site and the custom error locations 
%windir%\system32\inetsrv\appcmd set config -section:system.applicationhost/configHistory -path:%MOVETO%inetpub\history 
%windir%\system32\inetsrv\appcmd set config -section:system.webServer/asp -cache.disktemplateCacheDirectory:"%MOVETO%inetpub\temp\ASP Compiled Templates" 
%windir%\system32\inetsrv\appcmd set config -section:system.webServer/httpCompression -directory:"%MOVETO%inetpub\temp\IIS Temporary Compressed Files" 
%windir%\system32\inetsrv\appcmd set vdir "Default Web Site/" -physicalPath:%MOVETO%inetpub\wwwroot 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='401'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='403'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='404'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='405'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='406'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='412'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='500'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='501'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
%windir%\system32\inetsrv\appcmd set config -section:httpErrors /[statusCode='502'].prefixLanguageFilePath:%MOVETO%inetpub\custerr 
REM Make sure Service Pack and Hotfix Installers know where the IIS root directories are 
reg add HKLM\Software\Microsoft\inetstp /v PathWWWRoot /t REG_SZ /d %mOVETO%\inetpub\wwwroot /f 
reg add HKLM\Software\Microsoft\inetstp /v PathFTPRoot /t REG_SZ /d %MOVETO%\inetpub\ftproot /f 
REM Do the same for x64 directories 
if not "%ProgramFiles(x86)%" == "" reg add HKLM\Software\Wow6432Node\Microsoft\inetstp /v PathWWWRoot /t REG_EXPAND_SZ /d %MOVETO%inetpub\wwwroot /f 
if not "%ProgramFiles(x86)%" == "" reg add HKLM\Software\Wow6432Node\Microsoft\inetstp /v PathFTPRoot /t REG_EXPAND_SZ /d %MOVETO%inetpub\ftproot /f 
REM Restart all IIS services 
iisreset /start 
echo. 
echo. 
echo =============================================================================== 
echo Moved IIS7 root directory from %systemdrive%\ to %MOVETO%. 
echo. 
echo Please verify if the move worked. If so you can delete the %systemdrive%\inetpub directory. 
echo If something went wrong you can restore the old settings via 
echo     "APPCMD restore backup beforeRootMove" 
echo and 
echo     "REG delete HKLM\System\CurrentControlSet\Services\WAS\Parameters\ConfigIsolationPath" 
echo You also have to reset the PathWWWRoot and PathFTPRoot registry values 
echo in HKEY_LOCAL_MACHINE\Software\Microsoft\InetStp. 
echo =============================================================================== 
echo. 
echo. 
endlocal 
goto success 
REM error message if no argument or drive does not exist 
:err 
echo. 
echo New root drive letter required. 
echo Here an example how to move the IIS root to the F:\ drive: 
echo. 
echo MOVEIISROOT.BAT F 
echo. 
echo. 
:success

Select allOpen in new window

@hades666: How about like this:
From the IIS7, I right-click the Default Website-->Manage Website--> Advance Settings
then I just changed the Physical Path of the IIS, I just clicked the button on the path of the IIS. Before it's located @ C:\inetpub\wwwroot , then I moved to D:\IIS
Then I just restart the service of the IIS.

That is all you would need to do and that is all the script does as well.
The issue is how you moved it, I would use xcopy or robocopy to maintain the ACLS.
Cheers,
Hades666