How do I subclass in VB6 to capture user left mouse event on the title bar?

I want to capture the event when the user left-clicks on the title bar of a form in VB6....mouse down, mouse click etc. Thanks.....
LVL 4
jazjefAsked:
Who is Participating?
 
nffvrxqgrcfqvvcConnect With a Mentor Commented:
There is typo in previous example where the last line should be outside the If block statement. Below you can find a working example for detecting left double click, that will get you started then you can add the other events from the link above.

' Module1.bas

Option Explicit

Private Const WM_NCLBUTTONDBLCLK    As Long = &HA3&
Private Const HTCAPTION             As Long = &H2&
Private Const GWL_WNDPROC           As Long = (-4)

Private Declare Function SetWindowLongA Lib "User32.dll" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function CallWindowProcA Lib "User32.dll" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Private hWindow     As Long
Private func        As Long

Public Sub Attatch(ByVal hWnd As Long)
  If hWindow = 0 Then
    hWindow = hWnd
    func = SetWindowLongA(hWindow, GWL_WNDPROC, AddressOf WndProc)
  End If
End Sub

Public Sub Detatch()
  If hWindow <> 0 Then
    Call SetWindowLongA(hWindow, GWL_WNDPROC, func)
    hWindow = 0
  End If
End Sub
 
Public Function WndProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
If uMsg = WM_NCLBUTTONDBLCLK Then
  If wParam = HTCAPTION Then
  ' TODO:// Something when double clicked.
    Debug.Print "Double Clicked: "; Time
  End If
End If
WndProc = CallWindowProcA(func, hWnd, uMsg, wParam, lParam)
End Function



' Form1
Option Explicit

Private Sub Form_Load()
  Attatch Me.hWnd
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  Detatch
End Sub

Open in new window

0
 
nffvrxqgrcfqvvcCommented:
Begin with your normal subclassing routine but detect the non client area messages these are prefixed with (WM_NC) for example:

Mouse Input Notifications
http://msdn.microsoft.com/en-us/library/ff468877(v=VS.85).aspx 

WM_NCHITTEST
WM_NCLBUTTONDBLCLK
WM_NCLBUTTONDOWN
WM_NCLBUTTONUP
WM_NCMBUTTONDBLCLK
WM_NCMBUTTONDOWN
WM_NCMBUTTONUP
WM_NCMOUSEHOVER
WM_NCMOUSELEAVE
WM_NCMOUSEMOVE
WM_NCRBUTTONDBLCLK
WM_NCRBUTTONDOWN
WM_NCRBUTTONUP
WM_NCXBUTTONDBLCLK
WM_NCXBUTTONDOWN
WM_NCXBUTTONUP
In your WindowProc() method for example it would look something like this:
 

' Inside your WindowProc
Public Function WndProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
If uMsg = WM_NCLBUTTONDBLCLK Then
 If wParam = HTCAPTION Then
  ' TODO:// Something when double clicked.
 End If
 WndProc = CallWindowProcA(func, hWnd, uMsg, wParam, lParam)
End If
End Function

Open in new window

0
 
jazjefAuthor Commented:
Works great eql44. Thanks for teaching me how to do this. One small question.... is there a specific reason why it closes my development environment when I close the form? It shuts the form and my VB6 down when I click the X on the control box to exit.
0
Free Tool: Site Down Detector

Helpful to verify reports of your own downtime, or to double check a downed website you are trying to access.

One of a set of tools we are providing to everyone as a way of saying thank you for being a part of the community.

 
nffvrxqgrcfqvvcCommented:
Well it shouldn't but if you have an error in the WindowProc(WndProc) it will cause all kinds of problems so I have to ask you did you add/modify the example with some extra code?
 
0
 
jazjefAuthor Commented:
:) Yes. I did. But it's working now. Thanks for showing me how this is done eql1044---really helpful and very informative. And thanks for adding in the mouse input notifications.....
0
 
jazjefAuthor Commented:
Top-notch solution. Thanks eql1044.
0
Question has a verified solution.

Are you are experiencing a similar issue? Get a personalized answer when you ask a related question.

Have a better answer? Share it in a comment.

All Courses

From novice to tech pro — start learning today.