• Status: Solved
  • Priority: Medium
  • Security: Public
  • Views: 684
  • Last Modified:

How do I resize a loaded jpg image?

Hello,

I'm loading an image (from XML, decoded to a ByteArray) into a Sprite (see the code). I need to size it according to the width and height in the XML. How is this done?

Thanks!


var badgeholderPhotoBA:ByteArray = Base64.decodeToByteArray(badgeDataXML.BADGEREQUEST.PHOTO);
var badgeholderImageHolder:Sprite = new Sprite();
var badgeholderImageLoader:Loader = new Loader();

badgeholderImageLoader.loadBytes(badgeholderPhotoBA);
badgeholderImageHolder.addChild(badgeholderImageLoader);
badgeholderImageHolder.x = object.X;
badgeholderImageHolder.y = object.Y;

//this messes it up...how do I scale/resize the image????

badgeholderImageHolder.width = object.WIDTH as int;
badgeholderImageHolder.height = object.HEIGHT as int;

addChild(badgeholderImageHolder);

Open in new window

0
BlueKarana
Asked:
BlueKarana
2 Solutions
 
ActionScript_HelperCommented:
May be you can try resizing badgeholderImageLoader or badgeholderImageLoader.content.
==========================================================
badgeholderImageLoader.width = object.WIDTH as int;
badgeholderImageLoader.height = object.HEIGHT as int;

OR

badgeholderImageLoader.content.width = object.WIDTH as int;
badgeholderImageLoader.content.height = object.HEIGHT as int;
==========================================================

Another scenario may be that loadBytes are taking some time, and before that you are trying to scale image. So may be you should track complete event and than you should resize the image:

==========================================================
badgeholderImageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);

function imageLoaded(evt:Event):void
{
evt.target.content.width = object.WIDTH as int;
evt.target.content.height = object.HEIGHT as int;
}
==========================================================
0
 
bupperCommented:
You can definitely resize it to a specific size, but you may loose the proportions. Bad idea, unless the size in the XML is adjusted perfectly for that.

Instead, use the scale property:
yourmv.xscale = XSCALE;
yourmv.yscale = YSCALE;

Oh, and make sure you specify the forceSmoothing property (otherwise it will look grainy):
yourmv.forceSmoothing = true;
0
 
BlueKaranaAuthor Commented:
Both suggestions offer good advice (the loader event listener and smoothing), but there are a few details I was missing. I found help in a piece of code at tutorboy.com (see code for credit).

BTW, my photos are cropped to a certain aspect ratio for layout on a badge. If the user didn't crop at this point (print preview or print) the'll get a warning.

Smoothing is done differently in AS3 though. See onComplete in code. I did add smoothing for good measure.

If I "get it" fully, what I was missing was putting the loader, through the use of a LoaderInfo object, into a displayObject and changing the width and height of that. (Probably not using correct terminology. Still trying to figure this AS thing out!


/**
 * Adapted from ~~
 *
 * DATE: 19/April/2010
 * Dynamic Image load and resize
 * Email: midhund[at]tutorboy.com
 * Web: http://articles.tutorboy.com/
 **/

package{

	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.net.URLRequest;
	import flash.events.*;
	import flash.utils.ByteArray;
	import com.dynamicflash.util.Base64;
	
	 public class ImageLoader extends Sprite{
	 // loader vaiable to hold the image
	 protected var loader:Loader;
	 // set the image resize max width and max height.
	 //protected var maxW:Number = 400, maxW:Number = 500;
	 protected var newW:Number, newH:Number;
	 protected var newX:Number, newY:Number;
	 
	 public function ImageLoader(imageString:String, designW:Number, designH:Number, designX:Number, designY:Number):void {
		 newW = designW;
		 newH = designH;
		 newX = designX;
		 newY = designY;
		 loadImage(imageString);
	 }

	 public function loadImage(imageString:String):void {

		// create the loader instance from Loader class.
		 loader =  new Loader();
		//decode the photo from the encoded string and put it in a byte array
		var PhotoBA:ByteArray = Base64.decodeToByteArray(imageString);
		// create the loader instance from Loader class.
		 // add the event listener to the onComplete event.
		loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
		 // event listener for the IO error
		loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
		 // load the image to the loader component
		loader.loadBytes(PhotoBA);
		
		// create a new sprite to hold the loader.
		 var container:Sprite = new Sprite();
		 container.graphics.beginFill(0x000000);
		 container.graphics.drawRect(0, 0, newW, newH);
		 // place image according to badge design
		 container.x = newX;
		 container.y = newY;
		 		 
		 // add the loader to the sprite.
		 container.addChild(loader);
		 // add the container to the stage.
		 addChild(container);

	}
 
	 private function ioErrorHandler(event:IOErrorEvent):void {
		 trace("ioErrorHandler: " + event);
	 }

	 private function onComplete(event:Event):void {
		 // remove the complete listener from the loader component.
		 loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onComplete);
		 event.target.content.smoothing = true; //This is a Bitmap object

		 var loaderInfo:LoaderInfo = event.target as LoaderInfo;
		 var dispObj:DisplayObject = loaderInfo.content;
		 
		 dispObj.width = newW;
		 dispObj.height = newH;
		 //align the display object to its container
		 dispObj.x = 0;
		 dispObj.y = 0;
		 
	 }
 }
}

Open in new window

0

Featured Post

Free Tool: ZipGrep

ZipGrep is a utility that can list and search zip (.war, .ear, .jar, etc) archives for text patterns, without the need to extract the archive's contents.

One of a set of tools we're offering as a way to say thank you for being a part of the community.

Tackle projects and never again get stuck behind a technical roadblock.
Join Now