How to take run time 1)inputs, 2) call URL from batch script

to call user from batch file you can user following..

start http://google.com

---
But I don't understand your first question..

Thanks
Saugata

how to take the run time inputs ...

means ......

--------

---- start program ...

please enter your num: < user will input runtime>

---- programe should wait till the user provided input.  .. it is just like scanf-funtion in C-program.

I am attaching a Example Script, it's for user profile backup..

You will easily understand the option section..

Thanks
Saugata

@echo off
color 0c
REM PBR_AUTO.BAT
REM Created by Saugata Datta
REM Version 0.01
REM Auto Profile Backup and Restore
MODE CON: COLS=50 LINES=20
setlocal
%~d0
cd "%~dp0"
:_tsk
title Auto Profile Backup and Restore...
set _task=
cls
echo ___/FamilyCreditIndia_____________________________
echo       Auto Profile Backup and Restore
echo                    By : Saugata Datta
echo ________________________________________/WIPRO____

echo   [A] - Backup Domain Profile
echo   [B] - Restore Domain Profile
echo   [Q] - QUIT
echo.
set /p _task=Your Choice [in small]:
echo.
if "%_task%" == "a" goto _bkp
if "%_task%" == "b" goto _res
if "%_task%" == "q" goto _quit
if not "%_task%" == "a or b or q" goto _tsk

:_bkp
cd\
set /p _uname=Type user account Name:
%SystemDrive%
cd "Documents and Settings"
if not exist %_uname% (echo Wrong user name..
goto _bkp)
:_drv
set /p _drive=Type Drive letter[like D]:
if not exist %_drive%:\RECYCLER (echo Wrong drive...
goto _drv)
if exist "%_drive%:\%_uname%_apbr" ( echo Deleting old Backup
rmdir /s /q "%_drive%:\%_uname%_apbr")
mkdir "%_drive%:\%_uname%_apbr"
mkdir "%_drive%:\%_uname%_apbr\Favorites"
mkdir "%_drive%:\%_uname%_apbr\Desktop"
mkdir "%_drive%:\%_uname%_apbr\My Documents"
mkdir "%_drive%:\%_uname%_apbr\Recent"
mkdir "%_drive%:\%_uname%_apbr\Application Data"
mkdir "%_drive%:\%_uname%_apbr\Application Data\Microsoft"
mkdir "%_drive%:\%_uname%_apbr\Application Data\Microsoft\Office"
mkdir "%_drive%:\%_uname%_apbr\Application Data\Microsoft\Outlook"
mkdir "%_drive%:\%_uname%_apbr\Local Settings\History"
echo %cd%
xcopy /e /h /r /y "%_uname%\Favorites" "%_drive%:\%_uname%_apbr\Favorites"
xcopy /e /h /r /y "%_uname%\Desktop" "%_drive%:\%_uname%_apbr\Desktop"
xcopy /e /h /r /y "%_uname%\My Documents" "%_drive%:\%_uname%_apbr\My Documents"
xcopy /e /h /r /y "%_uname%\Application Data\Microsoft\Office" "%_drive%:\%_uname%_apbr\Application Data\Microsoft\Office"
xcopy /e /h /r /y "%_uname%\Application Data\Microsoft\Outlook" "%_drive%:\%_uname%_apbr\Application Data\Microsoft\Outlook"
xcopy /e /h /r /y "%_uname%\Local Settings\History" "%_drive%:\%_uname%_apbr\Local Settings\History"
goto _bsucc

:_res
cd\
set /p _uname=Type user account Name:
%SystemDrive%
cd "Documents and Settings"
if not exist %_uname% (echo Wrong user name..
goto _res)
:_drv2
set /p _rdes=Type backup drive:
if not exist %_rdes%:\RECYCLER (echo Wrong drive...
goto _drv2)
if not exist %_rdes%:\%_uname%_apbr (echo Old backup not available...
cd\
goto _res)
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\Favorites" "%_uname%\Favorites" 
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\Desktop" "%_uname%\Desktop"
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\My Documents" "%_uname%\My Documents"
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\Application Data\Microsoft\Office" "%_uname%\Application Data\Microsoft\Office"
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\Application Data\Microsoft\Outlook" "%_uname%\Application Data\Microsoft\Outlook"
xcopy /e /h /r /y "%_rdes%:\%_uname%_apbr\Local Settings\History" "%_uname%\Local Settings\History"
goto _rsucc

:_rsucc
@echo off
MODE CON: COLS=34 LINES=4
echo.
echo     *** Restore Successful ***
echo.
pause >nul
goto _quit

:_bsucc
@echo off
MODE CON: COLS=34 LINES=10
echo.
echo.
echo     *** Backup Successful ***
echo.
echo  Backup taken to following folder
echo.
echo         %_drive%:\%_uname%_apbr
pause >nul
goto _quit


:_quit
endlocal
exit

Select allOpen in new window

misterlupo,

absolutely good.

thanks for your help.

Small one..

Thanks
Saugata

@echo off
set _task=
set /p _task=Enter the URL you want to Open[e.g. http://google.com]:
start %_task%

Select allOpen in new window