Foxpro 2 gig dbf limit

Anyone had some experience with this Woody;s DBF Resizer:

************************************************************
* ResizeDbf 
************************************************************
* Copyright 2007 by wOOdy, ProLib Software GmbH, Germany
************************************************************
* This routine allows you to correct the filesize of a DBF
* depending on the desired Recordcount 
* It automatically takes care about the absolute maximum of 
* possible records
************************************************************

SET TALK OFF
CLEAR
USE

cFileName = GETFILE("DBF")
IF NOT FILE(cFileName)
	RETURN .f.
ENDIF

? "Filename", cFilename
ADIR(aFileInfo, cFileName)
nFileSize = aFileInfo(1,2)
? "Length of file ", nFileSize


nFile = FOPEN(cFileName,12)
IF nFile < 1
	MESSAGEBOX("Error at FileOpen")
	RETURN .F.
ENDIF

* Read the File characteristics from the header area
cHeader   = FREAD(nFile, 32)
nRecCount = CTOBIN(SUBSTR(cHeader, 5, 4), "4SR")
nHeader   = CTOBIN(SUBSTR(cHeader, 9, 2), "2SR")
nRecSize  = CTOBIN(SUBSTR(cHeader,11, 2), "2SR")   	


? "RecordCount", nRecCount
? "HeaderLength", nHeader
? "RecordLength", nRecSize

* Formula for the max number of possible records:
nMaxRec = Int((2^31-nHeader-2)/(nRecsize))
? "Max.Records   ", nMaxRec

nMaxrecNew = VAL(INPUTBOX("New Reccount","Input",TRANSFORM(nMaxRec),0,TRANSFORM(nMaxRec),"0"))
*nMaxRecNew = MIN(nMaxRec, nMaxRecNew)	 && just to be save from idiots
IF nMaxRecNew >0 
	IF MESSAGEBOX(TEXTMERGE("Set file <<cFileName>> to <<nMaxRecNew>> records?"),4+32+256) = 6 
		nNewSize = nHeader + (nRecSize * nMaxRecNew) 
 		FCHSIZE(nFile, nNewSize)	&& change the filesize
		FSEEK(nFile, 4,0)			&& reposition to the header (4 bytes move from Byte 1 = position 5)
		FWRITE(nFile, BINTOC(nMaxRec, "4SR"))	&& poke new reccount in reverse intel format
	ENDIF
ENDIF

FCLOSE(nFile)

TRY 
	USE (cFileName)
	GO BOTTOM
	BROWSE NOWAIT
CATCH
	? "Error on opening"
ENDTRY

Select allOpen in new window

Keep in mind that the 2GB limitation relates to the size for the DBF, FPT & CDX files themselves, not the record count.    
Admittedly I have not taken the time to try to understand the code above, but the text references all seem to be about 'records', not file size.

I have a client adding 100 meg. a month to one file and could reach the file limit size in about a year.

With that in mind, you can either do as I suggested above, and put the data into non-VFP database data table(s) (the preferred solution for best longevity) or you can distribute the data across multiple related VFP tables each of which would each be smaller in size.

Good Luck

"One way is to simply open another database, but he really likes having all the records in one place."

As long as you are talking about VFP, the 'database' is very seldom the issue.  
It is the 'data tables' (the DBF, CDX, & FPT files) that most often come up against the 2GB file limitation issue.  

Yes, if your VFP   DBC,DBX,DBT files (the 'database' files) were to exceed 2GB you would indeed have problems, but that is seldom the issue.

If "he" wants to be the one to design the data architecture, then, by all means, let him do it and let him experience the consequences.   But if 'he' wants things to work, then get him to be open to advice from others.

NOTE - putting the data into one or more SQL Server data tables would not only keep "all the records in one place", it would also add security to the data via SQL Server security.

Good Luck

wOOdys DBF resizer is adressing the probem of a dbf reaching the 2GB limit, to fix it back to all records below that limit, it does not extend dbfs to be capable to store more than 2GB.

"takes care about the absolute maximum of possible records" means it cuts off everything in the dbf above that limit, it does not extend the maximum. It truncates all records above 2GB. And it's also usable to fix a header corruption in regard to reccount.

You commented that line: *nMaxRecNew = MIN(nMaxRec, nMaxRecNew)       && just to be save from idiots

Now the program is not safe from idiots. Sorry, not to offend you, but if you extend a dbf to contain more records than nMaxRecNew computed a few lines before that, you're making the dbf file larger than 2GB but also inaccessable and not usable to foxpro anymore.

Bye, Olaf.

All the records in one place slow the performance down. You have to convince your client what means "one place" for database stored on file server. One Folder is the entity we are talking about...

Horizontal or vetical split is the only VFP solution today. (To wait for the next version is still not worth to do.)

BTW, does your client really need the data all together in one file? We are obviously working with (or reporting) a small subset. If they need e.g. monthly cumulative data then such data should be precalculated in separate tables for closed months and the only live data query should read current month which is much faster.

Thanks for the help guys.  I think we need to consider some sort of an SQL back end.