Solved

How to calculate product of a sequence?

Posted on 2011-02-25
9
342 Views
Last Modified: 2012-06-27
Please see attached image in order understand this very simple question:

Column K contains the formula I'm trying to figure out. I'm having to manually input these formulas and I'm trying to figure out a quick way to do it.

K52 =PRODUCT(1-J52)
K53 =PRODUCT(1-J52,1-J53)
K54 =PRODUCT(1-J52,1-J53,1-J54)

K55 should be = PRODUCT(1-J52,1-J53,1-J54, 1-J55)
...and so on...

Please let me know what would be a quick way to copy this formula down till row K127? Thanks.
Product-Sequence.JPG
0
Comment
Question by:Inciteful
9 Comments
 
LVL 9

Expert Comment

by:sshah254
ID: 34981534
K53 = PRODUCT(K52, 1-J53)
K54 = PRODUCT(K53, 1-J54)

and so on.

Ss
0
 
LVL 50

Expert Comment

by:barry houdini
ID: 34981569
Try this version

=PRODUCT(1-J$52:J52)

confirmed with CTRL+SHIFT+ENTER and copied down

Barry
0
 
LVL 81

Expert Comment

by:byundt
ID: 34981955
While both sshah254 and barryhoudini formulas work, you may prefer to dispense with PRODUCT altogether and copy down the following formula in cell K53
=(1-J53)*K52
0
Free Tool: IP Lookup

Get more info about an IP address or domain name, such as organization, abuse contacts and geolocation.

One of a set of tools we are providing to everyone as a way of saying thank you for being a part of the community.

 

Author Comment

by:Inciteful
ID: 34982468
Barry - i like your formula best.

One question though...

If I want to copy this formula across COLUMNS on another worksheet ? How would I set up the formula so that the references continue to work?

(Say the sheet in the image is called "sheet1")
0
 
LVL 50

Expert Comment

by:barry houdini
ID: 34982549
The $ fixes the row reference (makes it absolute) in the above so that when you copy down the J$52 remains J$52, if you want to copy across then it's the same principle but you use $ in front of the column letter so if you wanted to start with B4 and then add C4, D4 etc. you could use

=PRODUCT(1-$B4:B4)

then copy across

regards, barry
0
 
LVL 50

Expert Comment

by:barry houdini
ID: 34982584
Oh, I missed the sheet part, if that was on another sheet it would be like this

=PRODUCT(1-sheet1!$B4:B4)

still confirmed with CTRL+SHIFT+ENTER

....although if you want to avoid "array entering" you could add an INDEX function like this

=PRODUCT(INDEX(1-sheet1!$B4:B4,0))

regards, barry
0
 

Author Comment

by:Inciteful
ID: 34982607
Barry - when i copy that formula across columns A to Z the references dont change appropriately...
0
 
LVL 50

Accepted Solution

by:
barry houdini earned 500 total points
ID: 34983065
OK, I assumed you wanted to now make the references go across too, so you'd get the product of 1-B4 then the product of 1-B4, 1-C4 etc. but do you mean you want to copy the formula across but the references still go down?

If so then you can use OFFSET, e.g. if your data is on worksheet data then put this formula in B4, confirmed with CTRL+SHIFT+ENTER and copied across

=PRODUCT(1-OFFSET(data!$J52,0,0,COLUMNS($B4:B4)))

change B4 reference depending on your start cell

see attached, notice that the vertical results in Data sheet are the same as the horizontal ones in sheet1

regards, barry
26848133.xlsx
0
 

Author Closing Comment

by:Inciteful
ID: 35010592
thanks!
0

Featured Post

Free Tool: IP Lookup

Get more info about an IP address or domain name, such as organization, abuse contacts and geolocation.

One of a set of tools we are providing to everyone as a way of saying thank you for being a part of the community.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Approximate matching with VLOOKUP and MATCH seems to me to be a greatly under-used technique, and one which is vital for getting good performance out of large lookups. Until recently I would always have advised using an exact match for simplicity an…
This article descibes how to create a connection between Excel and SAP and how to move data from Excel to SAP or the other way around.
The viewer will learn how to create a normally distributed random variable in Excel, use a normal distribution to simulate the return on an investment over a period of years, Create a Monte Carlo simulation using a normal random variable, and calcul…
This Micro Tutorial demonstrate the bugs in Microsoft Excel for Mac with Pivot Charts.

830 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question