Batch file - xcopy - change files name if already present

That doesn't make much sense, as we cannot see how you want the folder name being added to the file name.
As far as I understood you want the folder name only if the file already exists. Again, that does not make much sense to me.
Maybe you should tell us more about what you REALLY want to achieve, so we can provide better help HOW to do it.

As the code is I search 1 drive of multiple directories and sub directories and copy those files into 1 folder. "test".  However this creates a files permissions errors since there different files with the same name in different folders. However the last folder before the root folder are different so I want to grab that folder name and append it to the file name so there unique.  Make sense??

Let's see.

@echo off
setlocal EnableDelayedExpansion
set src=C:\pst_files
set dst=c:\test
for /F "tokens=*" %%F in ('dir /s/b/a:-d %src%\*.pst') do (
   set folder=%%dpF
   set folder=!folder:%src%\=!
   for /F "tokens=1 delims=\" %%D in ("!folder!") do set folder=%%D
   copy "%%~F" "%dst%\%%nF.!folder!%%xF
)

Select allOpen in new window

That will copy e.g.   c:\pst_files\a\b\outlook.pst   to   c:\test\outlook.a.pst .

Ok, the code appears to only copy 1 file (im assuming the duplicate file); it changes the file type and labels the file "%nf.%dpfxf".  I also want to copy the all the .pst files (including the duplicates).

Thanks for your help.

Sorry, I'm stupid, forgetting the ~ each time. Try this:

@echo off
setlocal EnableDelayedExpansion
set src=C:\pst_files
set dst=c:\test
for /F "tokens=*" %%F in ('dir /s/b/a:-d %src%\*.pst') do (
   set folder=%%~dpF
   set folder=!folder:%src%\=!
   for /F "tokens=1 delims=\" %%D in ("!folder!") do set folder=%%~D
   copy "%%~F" "%dst%\%%~nF.!folder!%%~xF
)

Select allOpen in new window

Can you clarify the naming of the destination files a little more?  For example, if you have:

c:\pst_files\dir1\mail.pst
c:\pst_files\dir2\mail.pst

should those be copied as:

c:\pst_files\dir1\mail.pst  ==>  c:\test\mail.pst
c:\pst_files\dir2\mail.pst  ==>  c:\test\dir2_mail.pst

Or am I missing something?

~bp

I have interpreted it almost like you: First occurance should be copied as-is, each conflicting should be copied with the topmost folder name added (appended or prepended is not defined yet).

However, I expanded that to that the topmost folder name always is appended.

Ok, that works much better!  However it's not grabbing the last folder; but the 1st folder name of sub-directory for that file.

ex:
some_file
   some_file1
        user_file2

currently gives some_file.pst instead of user_file2.pst

I meant

ex:

some_folder
    some_folder1
          user_folder2

Points to Qlemo on this question, he's been working it with you, but I think this may do what you want.

@echo off
set src=c:\pst_files
set dst=c:\test
for /F "tokens=*" %%F in ('dir /s/b/a:-d %src%\*.pst') do (
   if not exist "%dst%\%%~nxF" (
      copy "%%~F" "%dst%\"
   ) else (
      for %%D in ("%%~pF\.") do copy "%%~F" "%dst%\%%~nD_%%~nxF"
   )
)

Select allOpen in new window

~bp

Sorry for the confusion!  Works great thanks!