Still celebrating National IT Professionals Day with 3 months of free Premium Membership. Use Code ITDAY17

x
?
Solved

I need an excel formula corrected

Posted on 2011-03-07
6
Medium Priority
?
330 Views
Last Modified: 2012-05-11
When I am trying to use the following formula, I get (0) returned and I know there should be a large number:

=SUMPRODUCT(((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)*(((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1))>0)*(Mansfield!$J$2:$J$10000)*(Mansfield!$K$2:$K$10000="N")

If I use this one, I get an anwser:

 =SUMPRODUCT((Mansfield!$C$2:$C$10000=DATA!A5)*(((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)*(((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1))>0)*(Mansfield!$J$2:$J$10000)*(Mansfield!$K$2:$K$10000="N"))

The only difference is ((Mansfield!$C$2:$C$10000=DATA!A5), which is a column and reference for a persons name. I am wanting the total for the values and am not looking for a specific name. Do I have some parenthesis out of whack?
0
Comment
Question by:wrt1mea
[X]
Welcome to Experts Exchange

Add your voice to the tech community where 5M+ people just like you are talking about what matters.

  • Help others & share knowledge
  • Earn cash & points
  • Learn & ask questions
6 Comments
 
LVL 59

Accepted Solution

by:
Saurabh Singh Teotia earned 1000 total points
ID: 35061796

This should work...

=SUMPRODUCT((((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)*(((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1))>0)*(Mansfield!$J$2:$J$10000)*(Mansfield!$K$2:$K$10000="N"))

If this is not working can you post worksheet...

Saurabh...
0
 
LVL 85

Assisted Solution

by:Rory Archibald
Rory Archibald earned 1000 total points
ID: 35061799
Yes:

=SUMPRODUCT((((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)*(((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1))>0)*(Mansfield!$J$2:$J$10000)*(Mansfield!$K$2:$K$10000="N"))
0
 
LVL 1

Author Closing Comment

by:wrt1mea
ID: 35062107
Both worked! Anyone care to explain what i did wrong?
0
Technology Partners: We Want Your Opinion!

We value your feedback.

Take our survey and automatically be enter to win anyone of the following:
Yeti Cooler, Amazon eGift Card, and Movie eGift Card!

 
LVL 50

Expert Comment

by:barry houdini
ID: 35062141
I think the parentheses were out as you suggested - in fact you can get rid of some more - this should work

=SUMPRODUCT(((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1)>0)*((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1)>0)*(Mansfield!$K$2:$K$10000="N"),Mansfield!$J$2:$J$10000)

regards, barry
0
 
LVL 1

Author Comment

by:wrt1mea
ID: 35062493
For some reason I always thought that if you opened the formula with 3 parentheses, you had to close it with that number too...
0
 
LVL 50

Expert Comment

by:barry houdini
ID: 35063177
Well, you obviously have to match the parentheses, for every one you open you must close one....but you can still do that correctly and get the formula wrong......

...in this formula (your first one)

=SUMPRODUCT(((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)*(((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1))>0)*(Mansfield!$J$2:$J$10000)*(Mansfield!$K$2:$K$10000="N")

.....you are missing a parenthesis at the start so in fact the SUMPRODUCT ends too early.......it's only this part

=SUMPRODUCT(((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1))>0)

because by that point you have closed as many parentheses as you have opened, so SUMPRODUCT is finished....and in the above there is no "co-ercer" [you aren't multiplying by anything or using *1 etc,] so it will always give a result of zero....then the rest of the formula will be irrelevant because whatever it is, you are multiplying by zero...so the result is going to be zero. Perhaps simpler to write like this

=SUMPRODUCT(
((Mansfield!$H$2:$H$10000>$P$1)+(Mansfield!$I$2:$I$10000>=$P$1)>0)+0,
((Mansfield!$H$2:$H$10000<=$Q$1)+(Mansfield!$I$2:$I$10000<=$Q$1)>0)+0,
(Mansfield!$K$2:$K$10000="N")+0,
Mansfield!$J$2:$J$10000
)

The function name and the opening bracket is on line 1 and the last line is just the closing bracket. Lines 2 , 3 and 4 are individula conditions and in each of those the brackets must match, line 5 is the sum range which doesn't need any.....

regards, barry

0

Featured Post

Enroll in September's Course of the Month

This month’s featured course covers 16 hours of training in installation, management, and deployment of VMware vSphere virtualization environments. It's free for Premium Members, Team Accounts, and Qualified Experts!

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

You need to know the location of the Office templates folder, so that when you create new templates, they are saved to that location, and thus are available for selection when creating new documents.  The steps to find the Templates folder path are …
In Part II of this series, I will discuss how to identify all open instances of Excel and enumerate the workbooks, spreadsheets, and named ranges within each of those instances.
This Micro Tutorial will demonstrate how to use a scrolling table in Microsoft Excel using the INDEX function.
Many functions in Excel can make decisions. The most simple of these is the IF function: it returns a value depending on whether a condition you describe is true or false. Once you get the hang of using the IF function, you will find it easier to us…

721 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question