Excel 2007 question - using VLOOKUP with Between Date function to return value

I have attached a spreadsheet that shows start and stop dates for certain volume targets (column I) by customer number (column A).  Some records are only one month total, others are many.

I need to take this information and condense it down to ~500 records starting in column M, that shows the customer volume for each month.  so for the first record on row 2, I need a formula that says to vlookup M2, then if the records in A2 through I14,000 has a date between columns F & G, then take the volume amount from column I and display.  Not sure if you can combine a VLOOKUP and a date between function, but that is what I'm trying to accomplish.  Thanks in advance. Book2.xlsx
carndarAsked:
Who is Participating?
 
barry houdiniConnect With a Mentor Commented:
Hello carndar/Brian,

Well spotted Brian - I picked up the #N/As, of course, which could be fixed with IFERROR as I suggested but there are some other discrepancies that I didn't notice.

Perhaps unwisely I didn't consider that there might be multiple entries matching the criteria.......

My VLOOKUP type approach finds a single value, whereas Brian's summing approach, as he says, will sum column I for all matching rows - the discrepancies come when there are overlapping date ranges - because of the nature of VLOOKUP with a missing 4th argument (equivalent to setting to TRUE) this means that the second entry is taken when there are two matches, e.g. for rows 6968 and 6969 where the date ranges overlap my suggestion takes the second entry which is zero. I assume that summing works in this case because it appears that there is always one entry with a zero and one non-zero, perhaps that wouldn't be legitimate if there were two equal non-zero values?

For the same results as Brian SUMIFS should be considerably more efficient in Excel 2007, i.e. with this formula

=SUMIFS($I$2:$I$15000,$A$2:$A$15000,$M2,$F$2:$F$15000,"<="&N$1,$G$2:$G$15000,">="&N$1)

regards, barry
0
 
barry houdiniCommented:
Hello carndar,

I put this formula in L2 copied down to L507 (hide if required or move somewhere else)

=COUNTIF(A:A,M2)

and then this formula in N2 copied across and down to AB507

=LOOKUP(N$1,INDEX($F$2:$F$15000,SUM($L$1:$L1)+1):INDEX($F$2:$F$15000,SUM($L$2:$L2)),INDEX($I$2:$I$15000,SUM($L$1:$L1)+1):INDEX($I$2:$I$15000,SUM($L$2:$L2)))

That could be shortened using OFFSET but the formula would probably be less efficient

Note: I formatted columns F and G as dates - that isn't strictly necessary but it won't affect the formula

see attached

regards, barry
27328856.xlsx
0
 
barry houdiniCommented:
...actually....better with VLOOKUP rather than LOOKUP, then it can be shorter, i.e. this formula in N2 copied across and down

=VLOOKUP(N$1,INDEX($F$2:$F$15000,SUM($L$1:$L1)+1):INDEX($I$2:$I$15000,SUM($L$2:$L2)),4)

see revised attachment

I note that there are some #N/A errors further down (because the date ranges for some codes don't start until 2011). If you want the formula can be modified to show zero, e.g. with IFERROR

=IFERROR(VLOOKUP(N$1,INDEX($F$2:$F$15000,SUM($L$1:$L1)+1):INDEX($I$2:$I$15000,SUM($L$2:$L2)),4),0)

barry
27328856v2.xlsx
0
Cloud Class® Course: Microsoft Windows 7 Basic

This introductory course to Windows 7 environment will teach you about working with the Windows operating system. You will learn about basic functions including start menu; the desktop; managing files, folders, and libraries.

 
redmondbCommented:
... and please see attached my version -

=SUM($I$2:$I$15000*($A$2:$A$15000=$M2)*(N$1>=$F$2:$F$15000)*(N$1<=$G$2:$G$15000))

Few points...
(1) Barry and I have, I think, differed in our handling of multiple entries matching the criteria. In any event, I have pasted Barry's values (from his first file) starting in column M and highlighted the differences in red.
(2) You mentioned row 14,000 as being the last to check, but there are a number of rows beyond that. Like Barry, I assumed that this was a misprint and used 15,000 instead.
(3) My formulas must be entered as array formulas so use Ctrl+Shift+Enter rather than simply Enter.

Regards,
Brian.

 Book2-V4.xlsx
0
 
redmondbCommented:
carndar,

The FormulaMeister's "SumIfs" is definitely the way to go - my "Sum" is an absolute dog (coming from an old dog, perhaps?).

Nice one Barry!

Regards,
Brian.
0
 
carndarAuthor Commented:
You guys are incredible!  Thanks for the quick response!
0
 
barry houdiniCommented:
Thanks for the comments carndar - it might be that SUMIFS was the best solution for you but please can you consider re-allocating the points here - I wouldn't have arrived at that solution without Brian's work - that was just a more efficient version of the formula Brian had already proposed - so a points split here would be more equitable I think

regards, barry
0
 
redmondbCommented:
Barry,

I appreciate your kind offer more than any points. I'm happy for things to be left as they are.

Swings and roundabouts!

Regards,
Brian.
0
Question has a verified solution.

Are you are experiencing a similar issue? Get a personalized answer when you ask a related question.

Have a better answer? Share it in a comment.

All Courses

From novice to tech pro — start learning today.