• Status: Solved
  • Priority: Medium
  • Security: Public
  • Views: 4114
  • Last Modified:

Use SumIf() function to sum cells from a matrix into a new matrix

I've got a worksheet that contains several hundred rows (similar to what is in rows A10:E10) on the attached spreadsheet.

What I'm looking for is a function (I think it is a combination of SumIf() and And() ) which I can use in all of the cells (same function in each cell of the range (H18:J20)) which will sum all of the values in the A10:E10 which match the values in the associated row and column headers.  Something like:

H18 = SumIf(B2:B10 = G18 and C1:E1 = H1, C2:E10)

Hope this makes sense.

I could write a function to do this, but before I go there, I thought I'd use check to see if some inventive expert could wrap this up in an already existing Excel function.

SumIf.xlsx
0
Dale Fye
Asked:
Dale Fye
  • 3
  • 3
  • 2
  • +2
2 Solutions
 
Saqib Husain, SyedEngineerCommented:
The simplest way to do this is a Pivot table.

Add labels to the first two columns
select the data
Insert > Pivot table < ok
In the choose fields pane
    drag the title of the second column to the "Row Labels" box
    drag each of the titles of the dates column to the "Sigma values" box

0
 
Saqib Husain, SyedEngineerCommented:
If you must have a formula you can enter

=SUMIF($B:$B,$G18,C:C)

in H18 and then copy it down and across
0
 
Rob HensonFinance AnalystCommented:
As you are using Excel 2007, you can use the SUMIFS function as this allows multiple criteria.

=SUMIFS(Criteria1Range,Criteria1,Criteria2Range,Criteria2,SumRange)

To be backwards compatible you would need to use SUMPRODUCT or an array formula. You can use the conditional sm wizard to set this up:

=SUM(IF(CriteriaRange1,Criteria1,CriteriaRange2,Criteria2),SumRange)

Thanks
Rob H
0
The new generation of project management tools

With monday.com’s project management tool, you can see what everyone on your team is working in a single glance. Its intuitive dashboards are customizable, so you can create systems that work for you.

 
Rob HensonFinance AnalystCommented:
Sorry, got the syntax for the SUM(IF... wrong!

Should be:

=SUM(IF(CriteriaRange1,Criteria1,IF(CriteriaRange2,Criteria2,SumRange),0),0)

This should be confirmed/entered with Ctrl + Shift + Enter which will add curly brackets at the start and finish.

Thanks
Rob H
0
 
barry houdiniCommented:
Hello fyed,

I don't think either of those approaches would work here Rob, because one of the criteria applies to the header row rather than the data in the columns.

For the example given Saqib's SUMIF suggestion above should be sufficient given that the date columns are in the same order in both the data and the summary table. If that isn't the case then you can use a formula like this

=SUMIF($B$2:$B$10,$G18,INDEX($C$2:$E$10,0,MATCH(H$17,$C$1:$E$1,0)))

using INDEX and MATCH to identify the correct column to sum.......or to allow multiple columns to match the date you can use this version with SUMPRODUCT

=SUMPRODUCT(($B$2:$B$10=$G18)*($C$1:$E$1=H$17),$C$2:$E$10)

regards, barry
0
 
barry houdiniCommented:
...Sorry Rob, I should correct that, I was partially wrong - SUMIFS can't work here - because the criteria ranges and sum range all need to be the same size and shape but......

....an array SUM(IF type formula, as you suggested, will work, similar to the SUMPRODUCT version I suggested. The syntax is slightly different, though. Would need to be like this using = signs to compare

=SUM(IF(CriteriaRange1=Criteria1,IF(CriteriaRange2=Criteria2,SumRange)))

which would equate to this for the example given

=SUM(IF($B$2:$B$10=$G18,IF($C$1:$E$1=H$17,$C$2:$E$10)))

confirmed with CTRL+SHIFT+ENTER

regards, barry
0
 
Rob HensonFinance AnalystCommented:
Hi Barry,

I had not looked at the sample data and had erroneously assumed that the date criteria were going to be in a column like the other criteria.

I knew (and almost said in my original comment) that you would come up with a SUMPRODUCT option.

Thanks
Rob H
0
 
xtermieCommented:
Its much easier to use the subtotal feature that is build in EXCEL.
Often, there are ready made solutions within the application rather than writing elaborate formulas.
Ensure that your data is sorted by Column B as per example.

You click within the data, select Subtotals tab from the Data tab, and select that when COLUMN B changes, a SUM is needed for ALL THREE DATES available as per example.
Excel will do the rest for you.

Check the sample attached.
SumIf-v1.xlsx
0
 
Dale FyeAuthor Commented:
I don't consider either of the solutions provided by Barry or Rob to be "elaborate", and since I need the results in another matrix (actually located on another workbook), my preferred method will be either the SumProduct solution or the Sum(IF(IF()) solution provided.

Thanks for your feedback.
0
 
Saqib Husain, SyedEngineerCommented:
fyed, you should be able to get the formula to work on the same sheet. Once that happens you can move the table to the other workbook.
0
 
Dale FyeAuthor Commented:
Thanks, guys.

Could have sworn that I awarded points for this the other day, but was having some internet connection issues, so it may not have gone through.

I should have thought of the nested IF's, but the SumProduct function was new to me, so I awarded more points to barry for teaching me something new (as well as actually filling in the row/column references, to help me visualize the function better.

One of these centuries, I'll be as proficient in Excel as I am in Access.

Thanks again.
0

Featured Post

Free Tool: Path Explorer

An intuitive utility to help find the CSS path to UI elements on a webpage. These paths are used frequently in a variety of front-end development and QA automation tasks.

One of a set of tools we're offering as a way of saying thank you for being a part of the community.

  • 3
  • 3
  • 2
  • +2
Tackle projects and never again get stuck behind a technical roadblock.
Join Now