access string: replace zeros

i have a field with a number of entries like




S202.005 and B20.0008

can i parse these to select and delete any zeros after the dota so they become

s202.5 B20.8

what would the query code be?
topUKlawyerAsked:
Who is Participating?
 
Dale FyeCommented:
Like I said, I would use a function.  The advantage is that you can add error handling and special processing to accommodate anomalies within your data.  I've included sample code here.  In a query, you could use something like:

Select [FieldName], ReformatField([FieldName]) as Reformatted
FROM yourTable

Hope this helps
Dale


Public Function ReformatField(SomeValue As Variant) As Variant

    Dim strLeft As String, strRight As String
    Dim intCharPos As String
   
    'Check to see whether the value passed was NULL
    'and if so, return NULL
    If IsNull(SomeValue) Then
        ReformatField = Null
        Exit Function
    End If
   
    'Check to see whether there is actually a period in the string
    'If not, return the original value
    intCharPos = InStr(SomeValue, ".")
    If intCharPos = 0 Then
        ReformatField = SomeValue
        Exit Function
    End If
   
    'You could also put some error checking in here to make sure
    'that the position of the period in the string is not the
    'first or last character.
   
    'Parse the string
    strLeft = left(SomeValue, intCharPos - 1)
    strRight = Mid(SomeValue, intCharPos + 1)
   
    'Remove leading zeros from the right side of the string
    'You could do this with the Replace function, but it would
    'replace all of the zeros, even if they were after the first
    'non-zero value
    While left(strRight, 1) = "0"
        strRight = Mid(strRight, 2)
    Wend
   
    ReformatField = strLeft & "." & strRight
       
End Function
0
 
DatabaseMX (Joe Anderson - Microsoft Access MVP)Database ArchitectCommented:
One way:


Left(YourField,InStr(1,YourField,".")) & val(Mid(YourField,InStr(1,YourField,".")+1))

Example:
Left("B20.0008",InStr(1,"B20.0008",".")) & val(Mid("B20.0008",InStr(1,"B20.0008",".")+1))
returns B20.8
0
 
Gustav BrockCIOCommented:
Another way:

strNum = Split(YourField, ".")(0) & "." & Val(Split(YourField, ".")(1))

/gustav
0
Ultimate Tool Kit for Technology Solution Provider

Broken down into practical pointers and step-by-step instructions, the IT Service Excellence Tool Kit delivers expert advice for technology solution providers. Get your free copy now.

 
p912sCommented:
And yet another way...

strField = Left(YourField, InStr(1, YourField, ".")) & Replace(Right(YourField, InStr(1, YourField, ".") - 2), "0", "")

HTH

Scot
0
 
DatabaseMX (Joe Anderson - Microsoft Access MVP)Database ArchitectCommented:
"the query code be?"

That implied this is in a query. So, Split() et al will not work ...

mx
0
 
hnasrCommented:
'assume your field name: ss
'assume . exists in all fields, otherwise you need to check for that.

SELECT ss, left(ss,instr(ss,".")-1) & replace(ss,"0","",instr(ss,".")) AS myField FROM myTable
0
 
Gustav BrockCIOCommented:
> So, Split() .. will not work [in query]

You are right, but the Split code looks nicer!

/gustav
0
 
DatabaseMX (Joe Anderson - Microsoft Access MVP)Database ArchitectCommented:
hnasr & p912s

What if the value is B20.000800999
You solution would replace ALL zeros
0
 
Dale FyeCommented:
Personally,  I would create a function to do this.  Complex queries like this lend themselves to functions which can be documented and include error handling.

If you put it in a function, you could use any of the ideas mentioned above.
0
 
aikimarkCommented:
In the following example, you would replace X with your field name.

left(x,instr(x,".")) & clng(mid(x,instr(x,".")+1))

Open in new window

0
 
DatabaseMX (Joe Anderson - Microsoft Access MVP)Database ArchitectCommented:
What happens if the data is B20.000800ABC

?
0
 
hnasrCommented:
This, I think,  is supposed to be a simple question, not a project to invite for further assumptions on the author's behalf.

"S202.005 and B20.0008
......
s202.5 B20.8

what would the query code be?"
0
 
DatabaseMX (Joe Anderson - Microsoft Access MVP)Database ArchitectCommented:
Well, that's just two samples of data.
0
 
topUKlawyerAuthor Commented:
wow some big hitting stuff here:many thanks all you guys...
I appreciate the learned discussion.

Fyed: why do you use Public function rather than Function.
0
 
Dale FyeCommented:
Just the way I was taught, 20 years ago. Have always done it that way.

In code modules they are all defined as Public, in Form and Report modules, I generally make them private, unless I want to be able to call that function from some outside the form/report.
0
 
Gustav BrockCIOCommented:
Joe's original could handle Nulls this way:

Code: Left(YourField,InStr(1,Nz(YourField),".")) & Val(Mid(Nz(YourField),InStr(1,Nz(YourField),".")+1))

/gustav
0
 
topUKlawyerAuthor Commented:
Thanks everyone.

I havent got time to test them all but my eye was drawn to fyeds function solution which i tried and worked very well.

Also it introduced me to "while....wend" which I hadnt come across before and for those not particularly logical reasons I am awarding the points to fyed. Thanks for all replying and I may well be able to test and use your solutions in the future.
0
Question has a verified solution.

Are you are experiencing a similar issue? Get a personalized answer when you ask a related question.

Have a better answer? Share it in a comment.

All Courses

From novice to tech pro — start learning today.