Excel searching column multiple conditions

Hi All,

I have a question regarding searching an unordered list of data with multiple conditions. I have attached a file of what I am trying to do.

Essentially I want to search column G, total sales, for the first value that meets 2 (or potentially more) conditions.

In the example i have highlighted in yellow, I am looking to return the first date where the date is greater than April 1 AND the Total Sales exceeds 150.

I have been able to do this with a single condition, highlighted in orange (or whatever you would like to call that color). The formula I am using there is:

=INDEX(Sales[Date],MATCH(TRUE,Sales[Total Sales]>=150,0))

Open in new window


I just can't seem to get this to work with AND statements.

In this example there are 2 conditions, but I may like to include more in the future.

I am just looking for the simplest and most elegant way to do this.

Many thanks in advance
stokenatorAsked:
Who is Participating?
I wear a lot of hats...

"The solutions and answers provided on Experts Exchange have been extremely helpful to me over the last few years. I wear a lot of hats - Developer, Database Administrator, Help Desk, etc., so I know a lot of things but not a lot about one thing. Experts Exchange gives me answers from people who do know a lot about one thing, in a easy to use platform." -Todd S.

karunamoorthyCommented:
where is the attached file?
0
stokenatorAuthor Commented:
Attached is the sample file - my apologies.

I have highlight the expected result in yellow. many thanks
sample-file.xlsx
0
byundtMechanical EngineerCommented:
Assuming that there is an answer, you might try an array formula like:
=INDEX(F$2:F$1000,MATCH(1,(F$2:F$1000>=--"4/1/12")*(G$2:G$1000>=150),0))

To array-enter a formula:
1) Select the cell and paste the formula in the formula bar
2) Hold Control and Shift keys down
3) Hit Enter, then release all three keys

Excel should respond by putting curly braces { } surrounding your formula. If not (or if you see #N/A), then repeat steps 1-3.


If you need to verify that there is an answer before returning the date, then try array-entering:
=IF(COUNTIFS(F$2:F$1000,">=4/1/12",g$2:G$1000,">=150")=0,"",INDEX(F$2:F$1000,MATCH(1,(F$2:F$1000>=--"4/1/12")*(G$2:G$1000>=150),0)))

Brad
0
Get your problem seen by more experts

Be seen. Boost your question’s priority for more expert views and faster solutions

dlmilleCommented:
Brad - I just learned something

--"4/1/12" converts to date, like doing DATEVALUE("4/1/12")

A bit cryptic but easy on the typing ;)

Dave
0
byundtMechanical EngineerCommented:
Dave,
I've been using that short-cut with dates for so long, I forget that it isn't the official way of doing things. :-)         One thing I don't know, however, is how it works for people who have d-m-yy as the default date structure.

Brad


On the original question, I forgot about using IFERROR. Using it will shorten the alternative formula to:
=IFERROR(INDEX(F$2:F$1000,MATCH(1,(F$2:F$1000>=--"4/1/12")*(G$2:G$1000>=150),0)),"")

It still must be array-entered.
0
stokenatorAuthor Commented:
Thankyou so much Brad, that is perfect!

There is one other task that i need to adapt this formula to accomplish and I can't seem to do it. I hope that you're able to assist.

I have uploaded a new version of my sample file. The expected value is highlighted in RED.

After I return the date from the first example, I want to calculate the minimum sales between the 2 dates.

Simply put I want to search the list and return the minimum sales between 2 dates.

I would really appreciate it if you could assist with this as well.

Regards,

Stokenator
sample-file-V2.xlsx
0
byundtMechanical EngineerCommented:
Matt,
I see that you put your sales data in a table. That's a good practice, so I rewrote the original formula plus the newly requested one as:
=INDEX(Sales[Date],MATCH(1,(Sales[Date]>=--"4/1/12")*(Sales[Total Sales]>=150),0))   first over 150
=MIN(IF((Sales[Date]>=--"4/1/12")*(Sales[Date]<=B3),Sales[Total Sales],""))    min sales
=INDEX(Sales[Date],MATCH(B5,IF((Sales[Date]>=--"4/1/12")*(Sales[Date]<=B3),(Sales[Total Sales]),""),0))     date of min sales

All of these are array formulas, so remember to Control + Shift + Enter.

Cell B3 contains the results of the first formula. Note you'll need to apply a date format to the result of the third formula.

Brad
0

Experts Exchange Solution brought to you by

Your issues matter to us.

Facing a tech roadblock? Get the help and guidance you need from experienced professionals who care. Ask your question anytime, anywhere, with no hassle.

Start your 7-day free trial
stokenatorAuthor Commented:
Brad - THANKYOU!

This is brilliant and just what I was looking for.
0
stokenatorAuthor Commented:
perfect solution
0
It's more than this solution.Get answers and train to solve all your tech problems - anytime, anywhere.Try it for free Edge Out The Competitionfor your dream job with proven skills and certifications.Get started today Stand Outas the employee with proven skills.Start learning today for free Move Your Career Forwardwith certification training in the latest technologies.Start your trial today
Microsoft Excel

From novice to tech pro — start learning today.