Find all values (names) in a column and list in a different range - Formula Dashboard

Not sure if the title best describes what I am trying to do. I have range (A1:C13) that contains a column of names, test dates and scores. J1 contains the name that I want to search through the table and list all of their test dates (dynamic list in F:G column). From the list of test dates I have entered an Array formula that will look up their score. I also added a chart that will change with each date entered. (It will be a mini dashboard that updates with new scores).

I am a little lost how how to go through the column find each entry for the name listed in the J column. I could do a vlookup, but it would stop at the first one it finds. I think it would be using the index function, small and an if statement based on a google search, but it is a bit over my head.

I attached a workbook to explain a little better. Thank you in advance for any help.
Brent
EE---Match-Index-Question--1-.xlsm
bvanscoy678Asked:
Who is Participating?
 
barry houdiniConnect With a Mentor Commented:
Hello Brent, assuming nobody will take two tests on the same day you could use this formula in F3

=IFERROR(INDEX(B$2:B$13,SMALL(IF(A$2:A$13=J$1,ROW(A$2:A$13)-ROW(A$2)+1),ROWS(F$3:F3))),"")

confirmed with CTRL+SHIFT+ENTER and copied down as far as you might need

...and this version in G3 (your formula but with added IF function)

=IF(F3="","",INDEX(C$2:C$13,MATCH(1,(J$1=A$2:A$13)*(F3=B$2:B$13),0)))

also "array entered"

see attached

Edit: if it's possible for people to have two tests on the same day then the F3 formula can remain the same but G3 version should be this

=IFERROR(INDEX(C$2:C$13,SMALL(IF(A$2:A$13=J$1,IF(B$2:B$13=F3,ROW(A$2:A$13)-ROW(A$2)+1)),COUNTIF(F$3:F3,F3))),"")

regards, barry
multi-lookup.xlsm
0
 
bvanscoy678Author Commented:
Barry,

Yes, that works. No wonder it was above my head. To answer your question, it will not be possible to take more than one test in a day, so the first formula will work.

Thank you for the time and answer,
Brent
0
 
bvanscoy678Author Commented:
Thank you.
0
Question has a verified solution.

Are you are experiencing a similar issue? Get a personalized answer when you ask a related question.

Have a better answer? Share it in a comment.

All Courses

From novice to tech pro — start learning today.