Excel formula to get the Max of a number from a range, where the max is below a specific number

In the example attached, how can I adjust the formula so that it picks the max of the LookupDate that is before today's date?

Assuming today is 1/10/2013

ie, pick the red ResultDate instead of the yellow

=INDEX(Table92[ResultDate],MATCH(MAX(IF(Table92[code]=$G9,Table92[LookupDate],0)),Table92[LookupDate],0))

Open in new window


Thank You
example.xlsx
newparadigmzAsked:
Who is Participating?
 
leptonkaConnect With a Mentor Commented:
What about this:

=MAX(IF((Table92[code]=G6)*(Table92[LookupDate]<TODAY()),Table92[ResultDate],0))

Open in new window

ctrl+shift+enter, too.

Cheers,
Kris
0
 
Patrick MatthewsConnect With a Mentor Commented:
Try:

=INDEX(Table92[ResultDate],MATCH(MAX(IF((Table92[code]=$G9)*(Table92[LookupDate]<TODAY()),Table92[LookupDate],0)),Table92[LookupDate],0))

Open in new window


Array-entered, of course :)
0
 
newparadigmzAuthor Commented:
does this line work the way sumproduct works, by generating an array of boolean 0's and 1's and multiplying that by the data?

IF((Table92[code]=G6)*(Table92[LookupDate]<TODAY())

Open in new window

0
Get expert help—faster!

Need expert help—fast? Use the Help Bell for personalized assistance getting answers to your important questions.

 
leptonkaCommented:
It is two boolean expression multiplied - in this case multiplication is the same as AND logical operation, it means that both of the two conditions must be true. If both are true, we use the ResultDate, if not, we use 0. So the result is an array where you have dates only if the LookupDate is before today AND the code is the code you are looking for. All the other data is 0. So using max you have the maximum of these dates.
You can leave out IF and use this format which is similar to sumprodact:
=MAX((Table92[code]=G7)*(Table92[LookupDate]<TODAY())*Table92[ResultDate])

Open in new window

Because if one of the conditions is not true, the multiplication gives 0. If the conditions are true, the booleans = 1, so you can multiply with the ResultDate. The array is exactly the same as above.

Cheers,
Kris
0
 
barry houdiniConnect With a Mentor Commented:
I don't think you can simply compare the LookupDate column directly to TODAY() because your LookupDates aren't true dates, they are just numbers, so the comparison Table92[LookupDate]<TODAY() always returns FALSE - try converting today's date to a similar format within the formula, i.e. with TEXT function like this

=TEXT(TODAY(),"yyyymmdd")+0

So that makes the revised formula

=INDEX(Table92[ResultDate],MATCH(MAX(IF((Table92[ code ]=$G6)*(Table92[LookupDate]<TEXT(TODAY(),"yyyymmdd")+0),Table92[LookupDate],0)),Table92[LookupDate],0))

Edit - in that formula I needed to change the bolded part to [ code ] because otherwise it was being interpreted as a "code tag" - you may need to remove spaces - the correct version is in the attached file

see attached

Note that both your original formula and this revised version rely on no duplicates in that column (which seems to be the case) - if that isn't the case then formulas may fail

regards, barry
barry-example.xlsx
0
 
newparadigmzAuthor Commented:
Thanks!

The 'If' seemed to be necessary, although I do not know why.
0
All Courses

From novice to tech pro — start learning today.