[2 days left] What’s wrong with your cloud strategy? Learn why multicloud solutions matter with Nimble Storage.Register Now

Solved

COUNTIFS formula not counting correctly

Posted on 2013-06-05

Microsoft Excel

1 solution

Medium Priority

587 Views

Last Modified: 2013-06-06

Hello, I'm using:

=SUM(COUNTIFS($P:$P, "Program Planning & Policy",$O:$O, {"AZ","CA","DC","IN","LA","ME","MI","NC","NY","PR","TX","VT","WA"},$S:$S, {"Reg.","IS"}))

To try an count some data, however it seem if I try to add the add the additional criteria to the last range of "IS" the formula no longer works.... If I'm just counting for "Reg." or "IS" individually it counts correctly....

Why can't I count the last range for 2 criteria... is there an alternate work around apart from doing two COUNTIFS ala:

=SUM(COUNTIFS($P:$P, "Program Planning & Policy",$S:$S, "Reg.",$O:$O, {"AZ","CA","DC","IN","LA","ME","MI","NC","NY","PR","TX","VT","WA"}),COUNTIFS($P:$P, "Program Planning & Policy",$S:$S, "IS",$O:$O, {"AZ","CA","DC","IN","LA","ME","MI","NC","NY","PR","TX","VT","WA"}))
Dummy.xlsx

Comment

Question by:-Polak

[X]

Welcome to Experts Exchange

Add your voice to the tech community where 5M+ people just like you are talking about what matters.

Help others & share knowledge
Earn cash & points
Learn & ask questions

Join The Community

6 Comments

LVL 23

Expert Comment

by:NBVC

ID: 392230422013-06-05

It's because the criteria arrays aren't the same size....

Try:

=SUMPRODUCT((P1:P10="Program Planning & Policy")*(ISNUMBER(MATCH(O1:O10,{"AZ","CA","DC","IN","LA","ME","MI","NC","NY","PR","TX","VT","WA"},0)))*(ISNUMBER(MATCH(S1:S10,{"Reg.","IS"},0))))

adjust ranges to suit... but do not use unnecessarily large ranges.

LVL 50

Accepted Solution

by:barry houdini

barry houdini earned 2000 total points

ID: 392231182013-06-05

When you have 2 multi-element criteria ranges in COUNTIFS one needs to be separated by commas and one by semi-colons (assuming UK/US regional settings), so if you change the last comma , to a semi-colon ; your original formula will work, i.e.

=SUM(COUNTIFS($P:$P, "Program Planning & Policy",$O:$O, {"AZ","CA","DC","IN","LA","ME","MI","NC","NY","PR","TX","VT","WA"},$S:$S, {"Reg.";"IS"}))

If you have 3 or more multi-element criteria you need to use something like NB_VC's suggestion

regards, barry

LVL 1

Author Closing Comment

by:-Polak

ID: 392231542013-06-05

Thanks for the in-depth explaination of "why" and the cleaner solution.

LVL 23

Expert Comment

by:NBVC

ID: 392231772013-06-05

Hey barry,

Thanks.. you taught me something too :)

LVL 50

Expert Comment

by:barry houdini

ID: 392232592013-06-05

Thanks, note that even if the criteria arrays are the same size like this:

=SUM(COUNTIFS(A:A,{"a","b","c"},B:B,{"x","y","z"}))

then with comma separators for both you will only count a/x, b/y and c/z combinations. To count all combinations you still need to have commas for one and semi-colons for the other like this:

=SUM(COUNTIFS(A:A,{"a";"b";"c"},B:B,{"x","y","z"}))

regards, barry

LVL 23

Expert Comment

by:NBVC

ID: 392235362013-06-05

Oh, I see. Thanks again for elaborating. When I tested I got the correct result without realizing that they were aligned as you mentioned. :)

Featured Post

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Custom Document Properties in Excel

Article by: Martin

This article describes how you can use Custom Document Properties to store settings and other information in your workbook so that they will be available the next time you open the workbook.

Dynamic Data Vaildation

Article by: Rob

After seeing numerous questions for Dynamic Data Validation I notice that most have used Visual Basic to solve the problem. This suggestion is purely formula based and can be used in multiple rows.

Graph Data with Longer Labels in Excel

Video by: AnnieCushing

This Micro Tutorial will demonstrate how to use longer labels with horizontal bar charts instead of the vertical column chart.

Microsoft Excel

How to use the IF function in Excel

Video by: Bob

Many functions in Excel can make decisions. The most simple of these is the IF function: it returns a value depending on whether a condition you describe is true or false. Once you get the hang of using the IF function, you will find it easier to us…