Go Premium for a chance to win a PS4. Enter to Win

x
  • Status: Solved
  • Priority: Medium
  • Security: Public
  • Views: 410
  • Last Modified:

How do I use INDEX and MATCH in this specific Excel example ?

Hi,

I have an Excel 2010 workbook made up of two sheets (Dashboard and Summary) which shows the results from mobile app testing.  I'm trying to use INDEX and MATCH in the Dashboard sheet to return percentage values from the Summary sheet.

The idea is to locate the correct % value on the Summary sheet by providing a mobile device name (eg. iPhone 5) and a test result description (eg Pass).

The reason I am using INDEX/MATCH is because the device names may change, or new devices may be added. Therefore, I want to make it as flexible and maintainable as possible.

I've attached a mock-up of the original workbook.

Regards
Toco
iOS-Test-Control-Panel.xlsm
0
Tocogroup
Asked:
Tocogroup
  • 3
  • 2
1 Solution
 
NBVCCommented:
Try:

=INDEX(INDEX(Summary!$D:$D,MATCH($B3,Summary!$A:$A,0)):Summary!$D$1000,MATCH(C$2,INDEX(Summary!$B:$B,MATCH($B3,Summary!$A:$A,0)):Summary!$B$1000,0))

copied across the matrix.

Note:  This formula allows for items in Summary upto row 1000.. can be adjusted.
0
 
NBVCCommented:
Another way might be, first insert a column in Summary sheet before column A.. this can be hidden afterward....

Then insert formula in new A3:

=LOOKUP(REPT("z",255),B$3:B3)

copied down.


Now formula in Dashboard C3 is:

=SUMIFS(Summary!$E:$E,Summary!$A:$A,$B3,Summary!$C:$C,C$2)

copied across the matrix
0
 
TocogroupAuthor Commented:
Thank you. This works a treat.

I'm trying to understand how it works......how does the nested INDEX/MATCH combinations work ?
0
 
NBVCCommented:
Basically, since your column A lists the Mobile Devices once, per group, I am trying to index from the position of the matched Mobile Device to the end.... making the starting cell dynamic based on the mobile device.

This part:

INDEX(Summary!$D:$D,MATCH($B3,Summary!$A:$A,0))

finds the cell in column D that corresponds to the Mobile Device to search for.  This is where the outer INDEX function starts from, and it ends at D1000 according to:

INDEX(INDEX(Summary!$D:$D,MATCH($B3,Summary!$A:$A,0)):Summary!$D$1000

similarly, this inner INDEX function:

INDEX(Summary!$B:$B,MATCH($B3,Summary!$A:$A,0)):Summary!$B$1000,0)

finds the cell in column B that corresponds to match of mobile device in A.. and sets that as the start point, so that it gets the first occurance of the relevant Result for that mobile device.
0
 
TocogroupAuthor Commented:
That's clever !
Many thanks.
0

Featured Post

Microsoft Certification Exam 74-409

VeeamĀ® is happy to provide the Microsoft community with a study guide prepared by MVP and MCT, Orin Thomas. This guide will take you through each of the exam objectives, helping you to prepare for and pass the examination.

  • 3
  • 2
Tackle projects and never again get stuck behind a technical roadblock.
Join Now