asked on

EXTRACT FILE NAMES FROM A DIRECTORY TO A USABLE TEXT BASED LIST

I tried to do a search and found nothing useful. Our customer sent us a DVD with 5 main directory folders. Each of these 5 folders contains hundreds of subfolders. And each subfolder contains from 1 to as many as 10 part drawing in a standard PDF format. What I'd like to do is extract all the file names in these folders and subfolders and create a list which I can eventually manipulate in Excel to determine if we have ever made this part before. I think I can manage the back half of this little project, if I could just get a little help with creating the text list.

My network is based on WinServer 2003 w/AD. Workstations use XP Pro. I have the most experience using Excel with macros to get where I'm going.

Thanks in advance,

Bryan

ASKER CERTIFIED SOLUTION

Pavel Celba

membership

This solution is only available to members.

To access this solution, you must be a member of Experts Exchange.

Start Free Trial

Pavel Celba

You are asking in FoxPro zone so the following code will list the directory incl. subfolders. VFP 9 and a lot of memory is required to process large number of files:

CREATE TABLE dirlist (filename C(100))  && The column width should be greater than the longest file path on the DVD

LOCAL lcRootFolder, lcFileSkeleton
lcRootFolder = "F:"      && DVD drive
lcFileSkeleton = "*.*"

DO CreateDirList WITH ADDBS(m.lcRootFolder) + m.lcFileSkeleton

SELECT dirlist
COPY TO dirlist.txt TYPE DELIMITED

WAIT WINDOW "Done" NOWAIT


PROCEDURE CreateDirList
LPARAMETERS lcFileMask

WAIT WINDOW "Processing " + m.lcFileMask NOWAIT

LOCAL laDirs[1], laFiles[1], lnDirCnt, lnFileCnt, lnI

lnFileCnt = ADIR(laFiles, m.lcFileMask)
FOR lnI = 1 TO m.lnFileCnt
  INSERT INTO dirlist VALUES (ADDBS(JUSTPATH(m.lcFileMask)) + laFiles[m.lnI, 1])
NEXT

lnDirCnt = ADIR(laDirs, ADDBS(JUSTPATH(m.lcFileMask)) + "*.*", "D")
FOR lnI = 1 TO m.lnDirCnt
  IF !INLIST(laDirs[m.lnI, 1], '.','..')
    DO CreateDirList WITH ADDBS(JUSTPATH(m.lcFileMask)) + laDirs[m.lnI, 1] + '\' + JUSTFNAME(m.lcFileMask)
  ENDIF
NEXT

NOTE:  This character \  is backslash not the Korean Won currency symbol!

RETURN

Open in new window

ADIR function has additional parameters so you may decide what will be listed and what format of the filenames are on output.

The text output can be processed in Excel. You may decide about the different output format. See COPY TO command in VFP help.

You may test the code on some subfolder of your harddrive first.

Olaf Doschke

You can also do this as an Excel VBA Makro:

Dim row As Integer

Sub Start()
   GetDriveFiles "F:\"
End Sub

Sub GetDriveFiles(drive As String)
   Set o = CreateObject("Scripting.FileSystemObject")
   Set oFolder = o.GetFolder(drive)
   row = 1
   RecurseFolder oFolder
End Sub

Sub RecurseFolder(ByVal oFolder As Object)
    For Each oFile In oFolder.Files
       ActiveWorkbook.ActiveSheet.Cells(row, 1).Value = oFolder.Path + "\" + oFile.Name
       row = row + 1
    Next
   
    For Each oSubfolder In oFolder.SubFolders
       RecurseFolder oSubfolder
    Next
End Sub

Open in new window

Bye, Olaf.

SPINAL-FUSION

ASKER

Did exactly what I asked for. Sorry it took 3 days to test. I have been missing from the office due to health reasons. Thanks for the replies. And I may have posed in the wrong area as the VB base reply was more complicated than I needed.