• Status: Solved
  • Priority: Medium
  • Security: Public
  • Views: 404
  • Last Modified:

test to see if an number is greater than one standard deviation from mean in Excel

Experts,

Does anyone know how  code a formaul in Excel test to see if a number is greater than one standard deviation from the mean?
0
morinia
Asked:
morinia
  • 2
  • 2
2 Solutions
 
barry houdiniCommented:
Well, if you have a range of numbers like A1:A10 then you can get standard deviation of those numbers with

=STDEV(A$1:A$10)

......so if you want to test whether any specific number, like A1 is greater than one standard deviation from the mean use

=A1>AVERAGE(A$1:A$10)+STDEV(A$1:A$10)

that will give you TRUE or FALSE

See attached example - press F9 to generate new numbers

regards, barry

PS this version only gives you numbers at the top end - if you want to find any numbers that are more than 1 standard deviation away from the mean (either higher or lower) you can use this version

=ABS(A1-AVERAGE(A$1:A$10))>STDEV(A$1:A$10)
STDEV.xlsx
0
 
moriniaAdvanced Analytics AnalystAuthor Commented:
Barry,

This is great.  Is there any way to eliminate the high end and low end numbers when calculating the standard deviation?

I am able to do it when calculating the average by using this formula.

=(SUM(C29:G29)-MAX(C29:G29)-MIN(C29:G29))/(COUNT(C29:G29)-2)
0
 
barry houdiniCommented:
For a small range of numbers like that you could use this formula

=STDEV(SMALL(C29:G29,{2,3,4}))

or for any range

=STDEV(SMALL(range,ROW(INDIRECT("2:"&COUNT(range)-1))))

confirmed with CTRL+SHIFT+ENTER

Note: for the average without highest and lowest values you can simplify your version by using TRIMMEAN function, i.e.

=TRIMMEAN(C29:G29,2/COUNT(C29:G29))

regards, barry
0
 
moriniaAdvanced Analytics AnalystAuthor Commented:
Awesome.  Thanks.
0
Question has a verified solution.

Are you are experiencing a similar issue? Get a personalized answer when you ask a related question.

Have a better answer? Share it in a comment.

Join & Write a Comment

Featured Post

Cloud Class® Course: Amazon Web Services - Basic

Are you thinking about creating an Amazon Web Services account for your business? Not sure where to start? In this course you’ll get an overview of the history of AWS and take a tour of their user interface.

  • 2
  • 2
Tackle projects and never again get stuck behind a technical roadblock.
Join Now