Link to home
Start Free TrialLog in
Avatar of IO_Dork
IO_DorkFlag for United States of America

asked on

find second match if prior cell has same lookup value

What would be the best way to lookup values, if the next row contained same lookup value as the previous,so the first lookup (A5) pulls the first match and the second lookup (A6) with same value pulls the second match.
Avatar of byundt
byundt
Flag of United States of America image

Try array entering a formula like:
=IFERROR(INDEX(Sheet1!B$1:B$10,SMALL(IF(Sheet1!A$1:A$10=A5,ROW(Sheet1!B$1:B$10)-ROW(Sheet1!B$1)+1,""),COUNTIF(A$4:A4,A5)+1)),"")
This formula will return the first, second, third result from Sheet1 column B when Sheet1 column A contains the same value as cell A5. The formula returns an empty string (looks like a blank) when there are no more matches.

The above formula must be array-entered. To do so:
1.  Select the cell
2.  Click in the formula bar
3.  Hold the Control and Shift keys down
4.  Hit the Enter key, then release all three keys
Excel should respond by adding curly braces { } surrounding the formula. If not (or if you see a blank when there should be a value returned), then repeat steps 1 through 4
MultipleMatchesQ28323513.xlsx
Avatar of IO_Dork

ASKER

this is a long and tough one...maybe you could help me plug in the correct reference based on my current vlookup formula:

=VLOOKUP(A2,Prev!A:N,14,FALSE)
ASKER CERTIFIED SOLUTION
Avatar of byundt
byundt
Flag of United States of America image

Link to home
membership
This solution is only available to members.
To access this solution, you must be a member of Experts Exchange.
Start Free Trial
Avatar of IO_Dork

ASKER

I'll cleanup and simplify the workbook and pust it here later.  I have to leave now and travel for a few hours.
Avatar of IO_Dork

ASKER

columns H and N (highligted in yellow) on sheet "Curr" are the ones with the lookup formulas that need to be replaced with your formula.
lookup-sample.xlsx
Array formulas are sensitive to the number of rows being searched, and can cause an annoying recalc delay if you search entire columns (over a million rows). I had previously limited the array formula to 1000 rows of data, but suspect you may need more than that. In the workbook you posted, I expanded that to 10000 rows, and trust that you can increase it further if necessary.

Since most of the lookups were for the first value only, I decided to test whether the lookup value (A2) was the same as the previous row. If not, a regular VLOOKUP using entire columns would suffice. In so doing, you avoid the need for performing the array-entered part of the formula in most cases. Note that this construction assumes that column A has been sorted so duplicate values are in adjacent cells.

Resulting formula for column H:
=IFERROR(IF($A2<>$A1,VLOOKUP($A2,Prev!$A:$N,8,FALSE),INDEX(Prev!H:H,SMALL(IF(Prev!$A$1:$A10000=$A2,ROW(Prev!$A$1:$A$10000),""),COUNTIF($A$2:$A2,$A2)))),"")

Resulting formula for column N:
=IFERROR(IF($A2<>$A1,VLOOKUP($A2,Prev!$A:$N,14,FALSE),INDEX(Prev!N:N,SMALL(IF(Prev!$A$1:$A10000=$A2,ROW(Prev!$A$1:$A$10000),""),COUNTIF($A$2:$A2,$A2)))),"")

These formulas return an empty string (looks like a blank) if there was no match for A2. If you prefer #NA! error value, then shorten the formulas to:
=IF($A2<>$A1,VLOOKUP($A2,Prev!$A:$N,8,FALSE),INDEX(Prev!H:H,SMALL(IF(Prev!$A$1:$A10000=$A2,ROW(Prev!$A$1:$A$10000),""),COUNTIF($A$2:$A2,$A2))))

=IF($A2<>$A1,VLOOKUP($A2,Prev!$A:$N,14,FALSE),INDEX(Prev!N:N,SMALL(IF(Prev!$A$1:$A10000=$A2,ROW(Prev!$A$1:$A$10000),""),COUNTIF($A$2:$A2,$A2))))

All of the formulas in this Comment need to be array-entered.

The sample workbook shows the first pair of formulas in row 3 and following. It shows the second pair of formulas in row 2.

Brad
lookup-sampleQ28323513.xlsx
Avatar of IO_Dork

ASKER

so do i have to ctrl+shift enter these arrays one at a time or can I select all of column a and do the ctrl+shift all at once to make them arrays?
Do not select an entire column and array-enter the formula into all the cells. If you do, you will get the answer for the first row repeated in every cell in that column.

Instead CTRL + Shift + Enter the first formula. Then select that cell and double-click the little square at bottom right corner of the selection marquee. Excel will then copy down the array formula into all the data cells in that column.
Avatar of IO_Dork

ASKER

thanks, great solution.