Updates

To resolve the issue, make sure that you are logged on as an administrator, and then install the updates again. If the problem continues, use the SubInACL tool to repair file and registry permissions. To do this, follow these steps:
Download the SubInACL tool, and install it to the default path that is offered by the installer. The default path will be one of the following, depending on your version of Windows:
%ProgramFiles%\Windows Resource Kits\Tools (32-bit versions of Windows)
%ProgramFiles(x86)%\Windows Resource Kits\Tools (64-bit versions of Windows)
Start Notepad, and then copy and paste the following commands:

@echo off
 
setlocal
 
echo.
echo Determine whether we are on an 32 or 64 bit machine
echo.
 
if "%PROCESSOR_ARCHITECTURE%"=="x86" if "%PROCESSOR_ARCHITEW6432%"=="" goto x86
 
set ProgramFilesPath=%ProgramFiles(x86)%
 
goto startResetting
 
:x86
 
set ProgramFilesPath=%ProgramFiles%
 
:startResetting
 
echo.
 
if exist "%ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe" goto filesExist
 
echo ***ERROR*** - Could not find file %ProgramFilesPath%\Windows Resource Kits\Tools\subinacl.exe. Double-check that SubInAcl is correctly installed and re-run this script.
goto END
 
:filesExist
 
pushd "%ProgramFilesPath%\Windows Resource Kits\Tools"
 
subinacl.exe /subkeyreg HKEY_LOCAL_MACHINE /grant=administrators=f  /grant=system=f
subinacl.exe /subkeyreg HKEY_CURRENT_USER /grant=administrators=f  /grant=system=f
subinacl.exe /subkeyreg HKEY_CLASSES_ROOT /grant=administrators=f  /grant=system=f
subinacl.exe /subdirectories %windir% /grant=administrators=f /grant=system=f
 
echo FINISHED.
echo.
echo Press any key to exit . . .
pause >NUL
 
popd
 
:END
 
endlocal
Save the file as Reset.cmd.
Right-click the Reset.cmd file in File Explorer (in Windows 8.1 and Windows 8) or Windows Explorer (in Windows 7 and Windows Vista), and then click Run as administrator. In Windows XP, double-click the file in Windows Explorer.
Wait until the execution finishes, and then try to install the update again.